Archive for the 'Adobe' Category

Papervision Custom Primitive Source code for use with cool particle field effect.

Published

on September 9, 2008

in AS3, Adobe, Expert, Flash, Intermediate, Papervision, Particle, Particle Field, Primitive, Source Code and Tutorials

. 1 Comment

Carlos Lunetta was kind enough to send me his custom primitive and vertex particle classes for this blog entry. These are similar to the ones that he used for the Terra TV website. In this example that concept is rather simple. You create a primitive object (Plane, Cube, Sphere) and run a for loop on the verticles.

As shown here:

PLAIN TEXT

Actionscript:

for (var i:int = 0; i <disc.geometry.vertices.length; i++)
{
var discVert:Vertex3D = disc.geometry.vertices[i];
}

Link to my example

Source Code

Now that you are looping through the verticles of this primitive you are now privy to information such as the x y and z locations of each point. So what can we do with that.....

One thing we can do is attach particles to it.. such as

PLAIN TEXT

Actionscript:

for (var i:int = 0; i <disc.geometry.vertices.length; i++)
{
var discVert:Vertex3D = disc.geometry.vertices[i];
var vertexParticle:VertexParticle = new VertexParticle(particalMaterial, 5, discVert);
vertexParticle.x = discVert.x;
vertexParticle.y = discVert.y;
vertexParticle.z = discVert.z;
myParticles.addParticle(vertexParticle);
}

Doing this lends itself to some neat particle field effects such as the one shown above. Of course you can mess around with the settings to optimize it for your needs.

Here is how you put it all together:

PLAIN TEXT

Actionscript:

package com.cs54.papervision
{
import flash.events.Event;
import org.papervision3d.core.geom.Particles;
import org.papervision3d.core.geom.renderables.Particle;
import org.papervision3d.core.geom.renderables.Vertex3D;
import org.papervision3d.core.geom.Vertices3D;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.materials.special.MovieAssetParticleMaterial;
import org.papervision3d.materials.special.ParticleMaterial;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.materials.WireframeMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.objects.primitives.Cone;
import org.papervision3d.objects.primitives.Plane;
import src.primitives.Dome;
import src.primitives.Disc;
import src.primitives.VertexParticle;
public class PV3DScene extends PaperBase
{
protected var displayContainer :DisplayObject3D;
protected var particle :Particle
protected var myParticles :Particles;
protected var domeParticles :Particles;
protected var partMat :ParticleMaterial;
protected var colorMaterial :ColorMaterial;
protected var disc :Disc;
protected var particalMaterial :ParticleMaterial;
protected var particalMaterial2 :ParticleMaterial;
protected var container :DisplayObject3D;
protected var domeContainer :DisplayObject3D;
protected var dome :Dome;
override public function init(vpWidth:Number = 800, vpHeight:Number = 600):void
{
super.init(vpWidth, vpHeight);
default_camera.y = 800;
default_camera.rotationX = 20;
}
override protected function createChildren3D():void
{
super.createChildren3D();
container = new DisplayObject3D();
domeContainer = new DisplayObject3D();
default_scene.addChild(container);
default_scene.addChild(domeContainer);
default_camera.zoom = 50;
default_camera.z = -3000
colorMaterial = new ColorMaterial(0xFF0000, 1, true);
colorMaterial.doubleSided = true;
particalMaterial = new ParticleMaterial(0xFF00CC, 100, ParticleMaterial.SHAPE_CIRCLE);
particalMaterial2 = new ParticleMaterial(0x000000, 100, ParticleMaterial.SHAPE_CIRCLE);
myParticles = new Particles();
domeParticles = new Particles();
disc = new Disc(colorMaterial, 500,15,2,3,this);
dome = new Dome(colorMaterial, 500, 100, 10, 5, 2);
for (var i:int = 0; i <disc.geometry.vertices.length; i++)
{
var discVert:Vertex3D = disc.geometry.vertices[i];
var vertexParticle:VertexParticle = new VertexParticle(particalMaterial2, 5, discVert);
vertexParticle.x = discVert.x;
vertexParticle.y = discVert.y;
vertexParticle.z = discVert.z;
myParticles.addParticle(vertexParticle);
}
for (var j:int = 0; j <dome.geometry.vertices.length; j++)
{
var domeVert:Vertex3D = dome.geometry.vertices[j];
var domeVertexParticle:VertexParticle = new VertexParticle(particalMaterial, 5, domeVert);
domeVertexParticle.x = domeVert.x;
domeVertexParticle.y = domeVert.y;
domeVertexParticle.z = domeVert.z;
domeParticles.addParticle(domeVertexParticle);
}
container.addChild(myParticles)
domeContainer.addChild(domeParticles)
domeContainer.y = -10
default_scene.addChild(container)
default_scene.addChild(domeContainer);
}
override protected function renderEnterFrame(ThisEvent:Event):void
{
super.renderEnterFrame(ThisEvent);
if (default_camera.z <0)
{
default_camera.z += (0 - default_camera.z)*.01
}
default_camera.y += (50 - default_camera.y)*.01;
container.yaw(1);
domeContainer.yaw(1);
}
}
}

Paperbase.as

PLAIN TEXT

Actionscript:

package com.cs54.papervision
{
import flash.display.Sprite;
import flash.events.Event;
import org.papervision3d.view.Viewport3D;
import org.papervision3d.cameras.*;
import org.papervision3d.scenes.Scene3D;
import org.papervision3d.render.BasicRenderEngine;
public class PaperBase extends Sprite
{
public var viewport:Viewport3D;
public var renderer:BasicRenderEngine;
public var default_scene:Scene3D;
public var default_camera:Camera3D;
public function init(vpWidth:Number = 800, vpHeight:Number = 600):void
{
initPapervision(vpWidth, vpHeight);
createChildren3D();
createChildren2D();
size();
initEvents();
}
protected function initPapervision(vpWidth:Number, vpHeight:Number):void
{
viewport = new Viewport3D(vpWidth, vpHeight);
addChild(viewport);
renderer = new BasicRenderEngine();
default_scene = new Scene3D();
default_camera = new Camera3D();
}
protected function createChildren3D():void
{
// This function should hold all of the stages needed
// to initialise everything used for papervision.
// Models, materials, cameras etc.
}
protected function createChildren2D():void
{
// This function should create all of the 2d items
// that will be overlayed on your papervision project.
// User interfaces, Heads up displays etc.
}
protected function size():void
{
}
protected function initEvents():void
{
addEventListener(Event.ENTER_FRAME, renderEnterFrame);
}
protected function processFrame():void
{
// Process any movement or animation here.
}
protected function renderEnterFrame( ThisEvent:Event ):void
{
//trace("RENDERING")
//We need to render the scene and update anything here.
renderer.renderScene(default_scene, default_camera, viewport);
processFrame();
}
}
}

Here are Carlos Lunetta's classes for the Dome,Disc and VertexParticle

Dome.as

PLAIN TEXT

Actionscript:

package src.primitives
{
import org.papervision3d.core.geom.*;
import org.papervision3d.core.geom.renderables.Vertex3D;
import org.papervision3d.core.proto.*;
/**
* ...
* @author clunetta
*/
public class Dome extends TriangleMesh3D
{
private var segments:uint;
private var sides:uint;
private var radius:Number
private var height:Number;
private var sideIncrement:Number;
private var currentIncrement:Number = 0;
public function Dome (material:MaterialObject3D=null, radius:Number=100, height:Number = 100, segments:uint=0, sides:uint=3, sideIncrement:Number=0, initObject:Object=null )
{
super(material, new Array(), new Array());
this.segments = 1 + segments;
this.sides = sides;
this.radius = radius;
this.sideIncrement = sideIncrement;
this.height = 2 * height;
buildDome();
}
private function buildDome():void
{
var matInstance:MaterialObject3D = material;
var i:Number, j:Number, k:Number;
var aVertice:Array = this.geometry.vertices;
var oVtx:Vertex3D;
oVtx = new Vertex3D(0,height,0);
aVertice.push(oVtx);
for (j = 1; j <segments; j++) {
//var hRds:Number = (segments-j)* (height/segments)
var fZ:Number = height * Math.sin((segments-(j-1)) * (0.5*Math.PI) / segments);
//var fZ:Number = (height)*Math.sin((j-1)*(0.5*Math.PI/segments));
currentIncrement += sideIncrement;
var curSides:uint = uint(Math.floor(sides + currentIncrement));
for (i = 0; i <curSides; i++) {
var fRds:Number = j * radius / segments;
var fX:Number = fRds*Math.sin(i*(2*Math.PI/curSides));
var fY:Number = fRds*Math.cos(i*(2*Math.PI/curSides));
oVtx = new Vertex3D(fY,fZ,fX);
aVertice.push(oVtx);
}
}
this.geometry.ready = true;
}
}
}

Disc.as

PLAIN TEXT

Actionscript:

package src.primitives
{
import org.papervision3d.core.geom.*;
import org.papervision3d.core.geom.renderables.Vertex3D;
import org.papervision3d.core.proto.*;
/**
* ...
* @author clunetta
*/
public class Disc extends TriangleMesh3D
{
private var segments :uint;
private var sides :uint;
private var radius :Number;
private var sideIncrement:Number;
private var currentIncrement:Number = 0;
public function Disc (material:MaterialObject3D=null, radius:Number=100, segments:uint=0, sides:uint=3, sideIncrement:Number=0, initObject:Object=null )
{
super(material, new Array(), new Array());
this.segments = 1+ segments;
this.sides = sides;
this.radius = radius;
this.sideIncrement = sideIncrement;
buildDisc();
}
private function buildDisc():void
{
var matInstance:MaterialObject3D = material;
var i:Number, j:Number, k:Number;
var aVertice:Array = this.geometry.vertices;
var fZ:Number = 0;
var oVtx:Vertex3D;
oVtx = new Vertex3D(0,0,0);
aVertice.push(oVtx);
for (j = 0; j <segments; j++) {
currentIncrement += sideIncrement;
var curSides:uint = uint(Math.floor(sides + currentIncrement));
for (i = 0; i <curSides; i++) {
var fRds:Number = (j + 1) * radius / segments;
var fX:Number = fRds*Math.sin(i*(2*Math.PI/curSides));
var fY:Number = fRds*Math.cos(i*(2*Math.PI/curSides));
oVtx = new Vertex3D(fY,fZ,fX);
aVertice.push(oVtx);
}
}
this.geometry.ready = true;
}
}
}

VertexParticle.as

PLAIN TEXT

Actionscript:

package src.primitives
{
import org.papervision3d.core.geom.renderables.Particle;
import org.papervision3d.core.geom.renderables.Vertex3D;
import org.papervision3d.materials.special.ParticleMaterial;
/**
* ...
* @author clunetta
*/
public class VertexParticle extends Particle
{
public function VertexParticle(material:ParticleMaterial, size:Number, vertex:Vertex3D)
{
super(material, size);
super.vertex3D = vertex;
}
}
}

Source Code

Papervision Double Sided Plane (err sorta) :/

Published

Charlie

on September 1, 2008

in AS3, Adobe, Double Sided Plane, Expert, Flash, Intermediate, OOP, Papervision, Papervision Plane, Source Code, Tutorials and Uncategorized

. 2 Comments

As far as I know there are 2 options when creating a double sided plane. Double sided meaning a different material for each side.

Option 1:
Create two planes. Plane 1 with a z sorting of 1 and the other with 0 and the rotationY of one of those planes set to 180. You could then contain this in one display container.

Version 2:
Create one cube with a depth of 0. Then you just apply a material to the front and back. OK OK OK so this is not really a Plane... but I like this approach because it allows me to more easily use things like Bend Modifier.

If anyone has a better or more improved approach I would love to hear about it.

Here is what the code for Option 1:

PLAIN TEXT

Actionscript:

package com.cs54.ui
{
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.materials.MovieMaterial;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.objects.DisplayObject3D;
import com.everydayflash.pv3d.modifiers.Bend;
import flash.display.DisplayObject;public class Tree2Planes extends DisplayObject3D
{
[Embed(source="/assets/tree-side-1.png")]
public var TreeFront :Class;[Embed(source="/assets/tree-side-2.png")]
public var TreeBack :Class;
protected var treeFront :DisplayObject;
protected var treeBack :DisplayObject;
protected var treeFrontMat :MovieMaterial;
protected var treeBackMat :MovieMaterial;
protected var treeMatList :MaterialsList;
protected var _height :Number = 175;
protected var _width :Number = 191;
protected var _container :DisplayObject3D;
protected var plane1 :Plane;
protected var plane2 :Plane;
public function Tree2Planes():void
{
treeMatList = new MaterialsList();
treeFront = new TreeFront();
treeBack = new TreeBack();
//Tree Materials
treeFrontMat = new MovieMaterial(treeFront, true);
treeBackMat = new MovieMaterial(treeBack, true);
treeFrontMat.allowAutoResize = false;
plane1 = new Plane(treeFrontMat,_width,_height);
plane2 = new Plane(treeBackMat,_width,_height);
plane1.z = 1;
plane1.rotationY = 180;
_container = new DisplayObject3D();
addChild(_container);
_container.addChild(plane1);
_container.addChild(plane2);
}
public function get height():Number
{
return _height;
}
public function get width():Number
{
return _width;
}
}
}

Here is what the code for Option 2:

PLAIN TEXT

Actionscript:

package com.cs54.ui
{
import org.papervision3d.materials.MovieMaterial;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.objects.primitives.Cube;
import com.everydayflash.pv3d.modifiers.Bend;
import flash.display.DisplayObject;
public class Tree extends DisplayObject3D
{
[Embed(source="/assets/tree-side-1.png")]
public var TreeFront :Class;
[Embed(source="/assets/tree-side-2.png")]
public var TreeBack :Class;
protected var treeFront :DisplayObject;
protected var treeBack :DisplayObject;
protected var treeFrontMat :MovieMaterial;
protected var treeBackMat :MovieMaterial;
protected var treeMatList :MaterialsList;
protected var treeCube :Cube;
protected var _height :Number = 175;
protected var _width :Number = 191;
protected var _container :DisplayObject3D;
public function Tree():void
{
treeMatList = new MaterialsList();
treeFront = new TreeFront();
treeBack = new TreeBack();
//Tree Materials
treeFrontMat = new MovieMaterial(treeFront, true);
treeBackMat = new MovieMaterial(treeBack, true);
treeFrontMat.allowAutoResize = false;
treeFrontMat.animated = true;
treeMatList.addMaterial( treeFrontMat, "front" );
treeMatList.addMaterial( treeBackMat, "back" );
treeCube = new Cube(treeMatList, _width, 0, _height, 6, 6, 6);
var bend:Bend = new Bend(treeCube);
bend.quickBend(1, .1);
addChild(treeCube);
}
public function get height():Number
{
return _height;
}
public function get width():Number
{
return _width;
}
}
}

Papervision Collada – Spongebob SquarePants

Published

Charlie

on August 31, 2008

in AS3, Adobe, Collada, Expert, Intermediate, Model, OOP, Papervision and Source Code

. 0 Comments

View Collada Spongebob in Papervision

I had some time on my hands this weekend and decided to mess around with loading Collada models with Papervision. I snagged a few models from Google Sketchup and went to town. Also tried to work in some OOP instead of just having one huge papervision file. I really need to clean up the source but rest assured the full source will be posted soon.

Basic lesson is that you can load a Collada file with just actionscript (packaged as a zip or just the dae file)

PLAIN TEXT

Actionscript:

//Load zipped dae file
protected function loadKMZ():void
{
kmz = new KMZ();
kmz.load("model/spongebob_squarepants.zip");
kmz.addEventListener(FileLoadEvent.LOAD_ERROR, onKmzError);
kmz.addEventListener(FileLoadEvent.LOAD_COMPLETE, onKmzLoaded);
//Scale if needed
kmz.scale = 20;
container.addChild(kmz);
}
//load the dae file
protected function loadDAE():void
{
dae = new DAE();
dae.load("model/spongebob_squarepants.dae");
dae.addEventListener(FileLoadEvent.LOAD_ERROR, onDaeError);
dae.addEventListener(FileLoadEvent.LOAD_COMPLETE, onDaeLoaded);
container.addChild(dae);
}

Adobe Flash CS3 Shortcuts – Publish with no preview – Macbook (pro) Mac but Vista / XP users

Published

Charlie

on August 14, 2008

in Adobe, Beginner, Flash and Intermediate

. 4 Comments

Keyboard Mac

I realize this is no great secret in the flash world (changing your keyboard shortcuts). The default setting is (SHIFT F12). Like most Flash Developers / Designers we adapt to our surroundings. If that be using a PC / Mac / someone else's fla / code / etc. Over the past few months I was presented with several projects where I had to compile multiple fla files. This is not too bad until you do cntrl+enter wait for the preview - close it - ctrl+enter review the changes and start the process over again. So I finally started to use (SHIFT F12) but depending on when I rebooted or changed my apple prefs I kept adjusting my volume and long story short it was getting to be a pain.

I personally like using CTRL and Backspace (DELETE on mac keyboard). The only drawback is that you may accidentally delete something. :/ But 99.9% of the time its uber quick.

To get to the menu just go to "Edit" > "Keyboard Shortcuts..." - Duplicate the current set. The "Publish" option that does not also generate a preview is under "File" and about 1/2 ways down.

Hope this helps.

Papervision Popup Book : The source – Just the elements on the stage

Published

Charlie

on June 20, 2008

in AS3, Adobe, Expert, Flash, Papervision, Source Code and Tutorials

. 17 Comments

Sorry for putting this up so late. This code is only used to arrange the items on the stage. Much work and re-working will need to be done to even start to achieve the effect of the ecodazoo website. Anyways, perhaps this will get someones brain moving in the right direction and help lead us in the path to re-creating this effect fully. As soon as I get some free time I will post a version that is a true popup book in papervision.

If anyone gets a chance sooner to do some cool things with the code please shoot me an email or a blog post and I would love to share it, with myself and with everyone else.

Download : FLA - AS & SOURCE

Don't forget the other code you will need to compile:

1) Papervision 2.0

2) Tweener

PLAIN TEXT

Actionscript:

package {
import caurina.transitions.Tweener;
import org.papervision3d.cameras.FreeCamera3D;
import org.papervision3d.core.data.qTree.QuadTree;
import org.papervision3d.objects.DisplayObject3D;
import com.foomonger.utils.Later;
import flash.display.*;
import flash.events.Event;
import flash.events.MouseEvent;
import org.papervision3d.cameras.Camera3D;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.materials.MovieMaterial;
import org.papervision3d.objects.primitives.Cube;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.render.BasicRenderEngine;
import org.papervision3d.scenes.Scene3D;
import org.papervision3d.view.Viewport3D;
public class Main extends Sprite
{
private var __camera :FreeCamera3D;
private var __scene :Scene3D;
private var __viewport :Viewport3D;
private var __renderer :BasicRenderEngine;
private var __width :Number;
private var __height :Number;
private var __background :Shape;
protected var __wallLeft isplayObject;
protected var __wallRight isplayObject;
protected var __wallBack isplayObject;
protected var __floor :DisplayObject;
protected var __tree isplayObject;
protected var __monster :DisplayObject;
protected var __moveMatWallLeft :MovieMaterial;
protected var __moveMatRightWall :MovieMaterial;
protected var __moveMatWallBack :MovieMaterial;
protected var __moveMatFloor :MovieMaterial;
protected var __moveMatTree :MovieMaterial;
protected var __moveMatMonster :MovieMaterial;
protected var __plane_wallLeft lane;
protected var __plane_rightWall lane;
protected var __plane_wallBack lane;
protected var __floorPlane :Plane;
protected var __treePlane lane;
protected var __monsterPlane lane;
protected var __rotation :Number;
public function Main():void
{
init();
}
protected function init():void
{
__rotation = 0;
setDefaultWidthHeight();
createChildren();
initPapervision();
initMaterials();
initObjects();
initEvents();
}
protected function setDefaultWidthHeight():void
{
__width = 1000;
__height = 600;
}
protected function initPapervision():void
{
__scene = new Scene3D();
__camera = new FreeCamera3D();
__camera.zoom = 11;
__camera.z = -2000;
__camera.y = 20;
__viewport = new Viewport3D(__width,__height,false,true,true);
__renderer = new BasicRenderEngine();
addChild(__viewport);
}
protected function initMaterials():void
{
__moveMatRightWall = new MovieMaterial(__wallRight, true)
__moveMatWallLeft = new MovieMaterial(__wallLeft, true);
__moveMatWallBack = new MovieMaterial(__wallBack)
__moveMatFloor = new MovieMaterial(__floor);
__moveMatTree = new MovieMaterial(__tree, true );
__moveMatMonster = new MovieMaterial(__monster, true);
__moveMatRightWall.doubleSided = true;
__moveMatWallLeft.doubleSided = true;
__moveMatWallBack.doubleSided = true;
__moveMatTree.doubleSided = true;
__moveMatFloor.doubleSided = true;
__moveMatTree.doubleSided = true;
__moveMatMonster.doubleSided = true;
}
protected function initObjects():void
{
__monsterPlane = new Plane(__moveMatMonster, 184, 237, 4, 4);
__plane_rightWall = new Plane(__moveMatRightWall, 386, 239, 4,4)
__plane_wallBack = new Plane(__moveMatWallBack, 734, 240, 4,4);
__plane_wallLeft = new Plane(__moveMatWallLeft,386,239,4,4)
__floorPlane = new Plane(__moveMatFloor, 800, 800, 14,14);
__treePlane = new Plane(__moveMatTree, 79, 112, 4, 4);
__scene.addChild(__floorPlane);
__scene.addChild(__plane_wallBack);
__scene.addChild(__treePlane);
__scene.addChild(__plane_wallLeft);
__scene.addChild(__plane_rightWall);
__scene.addChild(__monsterPlane);
__floorPlane.y = -120;
__treePlane.y = -69;
__floorPlane.pitch(90);
__monsterPlane.z = -300;
__monsterPlane.x = 150;
__monsterPlane.y = -10;
__plane_wallBack.z += 340
__treePlane.z = 300;
__treePlane.x = -220;
__plane_wallLeft.x = -155;
__plane_rightWall.x = 155;
__plane_wallLeft.rotationY = -35;
__plane_rightWall.rotationY = 35
}
protected function initEvents():void
{
this.addEventListener(Event.ENTER_FRAME,render);
}
protected function render(e:Event):void
{
__renderer.renderScene(__scene, __camera, __viewport, true);
var moveXAmount:Number = (mouseX - 1000 / 2) * 4
var moveYAmount:Number = (mouseY - 600 / 2) * 2
if (moveYAmount <0)
{
moveYAmount = 0;
}
__camera.x = moveXAmount;
__camera.y = moveYAmount;
__camera.lookAt(__floorPlane)
}
protected function createChildren():void
{
//Movieclips with Export for AS in Library
__wallBack = new Wall_back();
__wallLeft = new Wall_left();
__wallRight = new Wall_right();
__floor = new Floor();
__tree = new Tree();
__monster = new Monster();
}
}
}

Papervision Popup Book : Source Code To Follow Shortly

Published

Charlie

on June 18, 2008

in AS3, Adobe, Expert, Flash and Papervision

. 5 Comments

While talking with Mike Britton this evening he sent me this link - http://www.ecodazoo.com/ If you surf around a bit you will eventually make your way to a Popup Book which was created with a custom engine (Sharikura 3D) written by Roxik. I decided to take a try at creating it in Papervision. So far I have some of the elements in place which in itself was kinda fun to put together. I would still need to get it to fold into a book but thought this was neat in itself to post.

Download : FLA - AS & SOURCE

Don't forget the other code you will need to compile:

1) Papervision 2.0

2) Tweener

Here is a link to my quick version

Controlling a Papervision Cube

Published

Charlie

on May 4, 2008

in AS3, Adobe, Flash, Intermediate, Papervision, Source Code and Tutorials

. 2 Comments

View Example

The goal for this example was to create a simple way to display a cube, then rotate it one side at a time. The image is just from Google Images which will be all 6 sides of the cube. This again like the exploding image example illustrates some control over your elements. You can easily modify this example to include mouse events that you can use trigger a view each side of the cube.

PLAIN TEXT

Actionscript:

package
{
import caurina.transitions.Tweener;
import com.foomonger.utils.Later;
import flash.display.*;
import flash.events.Event;
import org.papervision3d.cameras.Camera3D;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.materials.MovieMaterial;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.objects.primitives.Cone;
import org.papervision3d.objects.primitives.Cube;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.render.BasicRenderEngine;
import org.papervision3d.scenes.Scene3D;
import org.papervision3d.view.Viewport3D;
public class PapervisionControlledCube extends Sprite
{
private var __camera:Camera3D;
private var __scene:Scene3D;
private var __viewport:Viewport3D;
private var __renderer:BasicRenderEngine;
private var __cube:Cube;
private var __matList:MaterialsList;
private var __width:Number;
private var __height:Number;
private var __background:Shape;
//Only needed if you are linking the image from FlexBuilder
//[Embed(source="assets/brick.png")]
//public var Brick:Class;
protected var __brick:DisplayObject;
protected var __brickClip:MovieClip;
protected var __rotation:Number;
public function PapervisionControlledCube():void
{
init();
}
protected function init():void
{
__rotation = 0;
setDefaultWidthHeight();
//Only needed for flexbuilder
//setupStage();
//--------------------------
createChildren();
initPapervision();
initMaterials();
initObjects();
initEvents();
}
protected function setDefaultWidthHeight():void
{
__width = 500;
__height = 250;
}
protected function initPapervision():void
{
__scene = new Scene3D();
__camera = new Camera3D();
__camera.zoom = 11;
__camera.z = -5000;
__camera.y = 200;
__viewport = new Viewport3D(__width,__height,false,true,true);
__renderer = new BasicRenderEngine();
addChild(__viewport);
}
protected function initMaterials():void
{
__matList = new MaterialsList();
var movieMat:MovieMaterial = new MovieMaterial(__brickClip);
__matList.addMaterial( movieMat, "front" );
__matList.addMaterial( movieMat, "back" );
__matList.addMaterial( movieMat, "left" );
__matList.addMaterial( movieMat, "right" );
__matList.addMaterial( movieMat, "top" );
__matList.addMaterial( movieMat, "bottom" );
}
protected function initObjects():void
{
__cube = new Cube(__matList,250,130,130);
__scene.addChild(__cube);
Later.call(this,zoomIn,1000,true);
}
protected function zoomIn(e:Event = null):void
{
Tweener.addTween(__camera,{z:-1000,transition:"easeInOutQuint",time:1,onComplete:rotateCube})
}
//-----------------------------------------------------------------------
//Rotate Cube
//-----------------------------------------------------------------------
protected function rotateCube(e:Event = null):void
{
__rotation += 90;
Tweener.addTween(__cube,{rotationY:__rotation,delay:.6,transition:"easeInOutQuint",time:1,onComplete:rotateCube})
}
protected function initEvents():void
{
this.addEventListener(Event.ENTER_FRAME,render);
}
protected function render(e:Event):void
{
__renderer.renderScene(__scene,__camera,__viewport,true);
}
protected function createChildren():void
{
__brick = new Brick();
__brickClip = new MovieClip();
__brickClip.addChild(__brick);
}
//Only used in flexbuilder
private function setupStage():void
{
stage.stageWidth = __width;
stage.stageHeight = __height;
stage.align = "cc";
stage.scaleMode = "noScale";
stage.stageFocusRect = true;
}
}
}

Download Source

Other classes used:

1) Papervision 2.0

2) Foomonger's Code (Call Later)

3) Tweener

Papervision 2.0 – Getting started from a simple starting example

Published

Charlie

on May 4, 2008

in AS3, Adobe, Intermediate, Papervision and Tutorials

. 9 Comments

At first when trying to create my first few Papervision projects it seemed a bit overwhelming. As you work with it more and more you notice that there are really only a few elements for creating a simple Papervision project. Then you can forget about the code and just think about what cool things you can do.

For any Papervision 2.0 project you need:

PLAIN TEXT

Actionscript:

//As always your imports
import flash.display.*;
import flash.events.Event;
import org.papervision3d.scenes.Scene3D;
import org.papervision3d.view.Viewport3D;
import org.papervision3d.cameras.Camera3D;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.render.BasicRenderEngine;
//1) A Scene
var scene:Scene3D = new Scene3D()
//2) A Camera
var camera = new Camera3D()
//Setting the camera zoom to 11 will make sure your objects are rendered at 100%
camera.zoom = 11;
//3) A view area "viewport" - think of this as your canvas or stage for your 3D objects
var viewport:Viewport3D = new Viewport3D(500,300,false,true,true)
//4) A render engine
var renderer:BasicRenderEngine = new BasicRenderEngine();
//5) add the viewport to the stage
addChild(viewport);
//6) Something in your scene such as a Plane, Cube, Sphere, etc - in this case a plane with a black color material
var plane:Plane = new Plane(new ColorMaterial(0x000000),100,100)
//add your object to your scene
scene.addChild(plane)
//7) Create a loop for rendering your animation
this.addEventListener(Event.ENTER_FRAME,render);
function render(e:Event):void
{
//Add some simple animation
plane.rotationY += 2; //Could also be plane.yaw(2);
//Render the scene
renderer.renderScene(scene,camera,viewport,true);
}

Don't forget to download the latest Papervision code

The great thing is that if you build this once into a nice clean class, you can just keep re-using that class as your papervision starting place. Then you can do what you do best, create and have fun!

Start with this and add a cube or different materials and animations. Then toss in some Tweener code to get some cool movement effects. In a few days you'll have some amazing things.

Papervision 2.0 – Exploding and Rebuilding an Image

Published

Charlie

on May 1, 2008

in AS3, Adobe, Expert, Flash, Papervision, Source Code and Tutorials

. 12 Comments

[kml_flashembed movie="image-explode.swf" height="300" width="550" /]

I took some time last week to have some fun with Papervision. The goal was to just take an image (any image) and have it explode into pieces and then rebuild it. While searching around for code or tutorials I have only found a few where the items on the stage go back into a controlled state. So over the next few weeks I am going to try to create a few examples of things that could be used IN a website rather than having the Papervision BE the website. I am not sure that makes sense. While I love experiments I like to have things I can use on everyday websites. This example I probably be using when I launch my new site. It's just something to break away from the ole fade in and out motion.

If you want to test this code on your own computer you will need to download a few things first.

1) Papervision 2.0

2) Foomonger's Code (Call Later)

3) Tweener

4) The Source

PLAIN TEXT

Actionscript:

package
{
import flash.display.*;
import flash.events.*;
import flash.geom.Matrix;
import flash.geom.Point;
import caurina.transitions.*
import com.foomonger.utils.Later;
import org.papervision3d.cameras.FreeCamera3D;
import org.papervision3d.materials.BitmapFileMaterial;
import org.papervision3d.materials.MovieMaterial;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.render.BasicRenderEngine;
import org.papervision3d.scenes.Scene3D;
import org.papervision3d.view.Viewport3D;
public class PVImageExplode extends MovieClip
{
private var viewport :Viewport3D;
private var scene :Scene3D;
private var camera :FreeCamera3D;
private var block :BitmapFileMaterial;
private var movieBlock :MovieMaterial;
private var blocksArray :Array;
private var planeArray :Array;
private var clips_array :Array;
private var renderer :BasicRenderEngine;
private var __holder isplayObject3D;
private var __startCamZ :Number;
private var __homePage :MovieClip;
private var __grass isplayObject;
private var __grassHolder :MovieClip;
private var __col :Number;
private var __rows :Number;
private var __blockWidth :Number;
private var __blockHeight :Number;
private var __yawAmount :Number = 0;
public function PVImageExplode()
{
init()
}
private function init():void
{
createChildren();
size();
initPapervision();
initMaterials();
initObjects();
initEvents();
}
//-----------------------------------------------------------------------
//Adds image to the stage to be then broke apart
//-----------------------------------------------------------------------
protected function createChildren():void
{
__grassHolder = new MovieClip();
__grass = new GrassItem();
__grassHolder.visible = false;
__grassHolder.addChild(__grass)
addChild(__grassHolder);
}
protected function size():void
{
__col = 4;
__rows = 10;
}
//-----------------------------------------------------------------------
//Papervision init setup
//-----------------------------------------------------------------------
private function initPapervision():void
{
viewport = new Viewport3D(1000,600,false,true,false);
addChild(viewport);
scene = new Scene3D();
camera = new FreeCamera3D();
renderer = new BasicRenderEngine();
camera.zoom = 11;
__startCamZ = -6000
}
//-----------------------------------------------------------------------
//Papervision materials setup
//-----------------------------------------------------------------------
private function initMaterials():void
{
blocksArray = [];
clips_array = new Array();
var __w:int =Math.ceil(__grassHolder.width / __col);
var __h:int =Math.ceil(__grassHolder.height / __rows);
__blockWidth = __w;
__blockHeight = __h;
var matrix :Matrix;
var bitmap_data :BitmapData;
var point oint;
var clip :MovieClip;
var columns :Number = __col;
var cellWidth :Number = __blockWidth;
var cellHeight :Number = __blockHeight;
var cellX :Number
var cellY :Number
var bx :Number
var by :Number
var bitmap :Bitmap
for (var i:int=0; i <(__rows * __col); i++)
{
cellX = i % columns;
cellY = Math.floor(i / columns);
bitmap_data = new BitmapData(__w,__h,true,0x00FFFFFF);
matrix = __grassHolder.transform.matrix;
bx = (cellX * cellWidth);
by = cellY * cellHeight;
matrix.translate(-__w * cellX, -__h * cellY);
bitmap_data.draw(__grassHolder,matrix);
clip = new MovieClip();
clips_array.push(clip);
clip.id = i;
addChild(clip);
point = new Point(__grassHolder.x + __w * cellX, __grassHolder.y + __h * cellY);
bitmap =new Bitmap(bitmap_data);
clip.addChild(bitmap);
clip.visible = false;
clip.x = point.x;
clip.y = point.y;
}
for(var k:uint = 0;k<clips_array.length;k++)
{
movieBlock = new MovieMaterial(clips_array[k],true);
movieBlock.doubleSided = true;
blocksArray.push(movieBlock);
}
}
//-----------------------------------------------------------------------
//Papervision objects setup (planes etc)
//-----------------------------------------------------------------------
private function initObjects():void
{
planeArray = [];
__holder = new DisplayObject3D();
__holder.x = -420;
__holder.y = 280
scene.addChild(__holder);
for(var k:uint = 0;k<blocksArray.length;k++)
{
var plane:Plane = new Plane(blocksArray[k],__blockWidth,__blockHeight,3,3);
var columns:Number = __col;
var cellWidth:Number = __blockWidth;
var cellHeight:Number = -__blockHeight;
var cellX:Number = k % columns;
var cellY:Number = Math.floor(k / columns);
plane.x = (cellX * cellWidth);
plane.y = cellY * cellHeight;
planeArray.push({plane:plane,pX:plane.x,pY:plane.y,pZ:plane.z,pR:plane.rotationY})
__holder.addChild(plane);
}
Later.call(this, explode, 500, true);
}
//-----------------------------------------------------------------------
//Start enterframe render event
//-----------------------------------------------------------------------
public function initEvents():void
{
this.addEventListener(Event.ENTER_FRAME,renderEvent);
}
//-----------------------------------------------------------------------
//Killin it
//-----------------------------------------------------------------------
public function killEvents():void
{
this.removeEventListener(Event.ENTER_FRAME,renderEvent);
}
//-----------------------------------------------------------------------
//Render the stage
//-----------------------------------------------------------------------
protected function renderEvent(e:Event):void
{
for(var i:uint = 0; i<planeArray.length;i++)
{
var plane = planeArray[i].plane;
plane.yaw(__yawAmount);
}
renderer.renderScene(scene,camera,viewport);
}
protected function resumeYaw():void
{
__yawAmount = 10;
}
//-----------------------------------------------------------------------
//The explosive magic (could be on a button click instead of later calls)
//-----------------------------------------------------------------------
protected function explode(e:Event = null):void
{
for(var i:uint = 0; i<planeArray.length;i++)
{
var plane = planeArray[i].plane;
var __x:Number = Math.random() * 3000 - 1000;
var __y:Number = Math.random() * 1000 - 500;
var __z:Number = Math.random() * 1000 - 500;
var __rY:Number = Math.random()* 720;
Tweener.addTween(plane,{x:__x,y:__y,z:__z,rotationY:__rY,transition:"easeInOutQuint",time:1})
}
Tweener.addTween(camera,{z:__startCamZ,x:1000,y:-400,transition:"easeInOutQuint",time:1,onComplete:resumeYaw})
Later.call(this, putBackTogether, 5000, true);
}
//-----------------------------------------------------------------------
//The Humpty Dumpty
//-----------------------------------------------------------------------
protected function putBackTogether(e:Event = null):void
{
Tweener.addTween(camera,{z:-1000,x:0,y:0,transition:"easeOutQuint",time:.3})
__yawAmount = 0;
for(var i:uint = 0; i<planeArray.length;i++)
{
var plane:Plane = planeArray[i].plane;
var __x:Number = planeArray[i].pX
var __y:Number = planeArray[i].pY
var __z:Number = planeArray[i].pZ
var __rY:Number = planeArray[i].pR
Tweener.addTween(plane,{x:__x,y:__y,z:__z,rotationY:__rY,delay:.3,transition:"easeInOutQuint",time:1})
}
Later.call(this, explode, 5000, true);
}
}
}

RSS Feed

Archive for the 'Adobe' Category

Papervision Custom Primitive Source code for use with cool particle field effect.

Papervision Double Sided Plane (err sorta) :/

Papervision Collada – Spongebob SquarePants

Adobe Flash CS3 Shortcuts – Publish with no preview – Macbook (pro) Mac but Vista / XP users

Papervision Popup Book : The source – Just the elements on the stage

Papervision Popup Book : Source Code To Follow Shortly

Controlling a Papervision Cube

Papervision 2.0 – Getting started from a simple starting example

Papervision 2.0 – Exploding and Rebuilding an Image

Pages

Recent Posts

Recent Comments

Blogroll

Meta

Categories

Archives

March 2010
M	T	W	T	F	S	S
« Feb
1	2	3	4	5	6	7
8	9	10	11	12	13	14
15	16	17	18	19	20	21
22	23	24	25	26	27	28
29	30	31

Archive for the 'Adobe' Category

Pages

Recent Posts

Recent Comments

Tags

Blogroll

Meta

Categories

Archives